Exports de GDScript¶
Introducción a exports¶
En Godot, los miembros de clase se pueden exportar. Esto significa que su valor se guardará junto con el recurso (p. ej. scene) al que están unidos. Estos también estarán disponibles para su edición en el editor de propiedades. La exportación se hace usando la palabra clave export
:
extends Button
export var number = 5 # Value will be saved and visible in the property editor.
Una variable exportada debe de ser inicializada como una expresión constante o tener una indicación de exportación (export hint) en forma de argumento para la palabra clave `export`(ver la sección de ejemplos).
Uno de los beneficios fundamentales de exportar (exponer) variables miembro es poder verlas y modificarlas en el editor. De este modo los artistas y los diseñadores de juegos pueden modificar estos valores, que luego influenciarán en cómo el programa se ejecuta. Para ésto, se proporciona una sintaxis especial.
Nota
Las propiedades pueden ser exportadas también en otros lenguajes, como C#. La sintaxis variará dependiendo del lenguaje.
Ejemplos¶
# If the exported value assigns a constant or constant expression,
# the type will be inferred and used in the editor.
export var number = 5
# Export can take a basic data type as an argument, which will be
# used in the editor.
export(int) var number
# Export can also take a resource type to use as a hint.
export(Texture) var character_face
export(PackedScene) var scene_file
# There are many resource types that can be used this way, try e.g.
# the following to list them:
export(Resource) var resource
# Integers and strings hint enumerated values.
# Editor will enumerate as 0, 1 and 2.
export(int, "Warrior", "Magician", "Thief") var character_class
# Editor will enumerate with string names.
export(String, "Rebecca", "Mary", "Leah") var character_name
# Named enum values
# Editor will enumerate as THING_1, THING_2, ANOTHER_THING.
enum NamedEnum {THING_1, THING_2, ANOTHER_THING = -1}
export(NamedEnum) var x
# Strings as paths
# String is a path to a file.
export(String, FILE) var f
# String is a path to a directory.
export(String, DIR) var f
# String is a path to a file, custom filter provided as hint.
export(String, FILE, "*.txt") var f
# Using paths in the global filesystem is also possible,
# but only in scripts in "tool" mode.
# String is a path to a PNG file in the global filesystem.
export(String, FILE, GLOBAL, "*.png") var tool_image
# String is a path to a directory in the global filesystem.
export(String, DIR, GLOBAL) var tool_dir
# The MULTILINE setting tells the editor to show a large input
# field for editing over multiple lines.
export(String, MULTILINE) var text
# Limiting editor input ranges
# Allow integer values from 0 to 20.
export(int, 20) var i
# Allow integer values from -10 to 20.
export(int, -10, 20) var j
# Allow floats from -10 to 20 and snap the value to multiples of 0.2.
export(float, -10, 20, 0.2) var k
# Allow values 'y = exp(x)' where 'y' varies between 100 and 1000
# while snapping to steps of 20. The editor will present a
# slider for easily editing the value.
export(float, EXP, 100, 1000, 20) var l
# Floats with easing hint
# Display a visual representation of the 'ease()' function
# when editing.
export(float, EASE) var transition_speed
# Colors
# Color given as red-green-blue value (alpha will always be 1).
export(Color, RGB) var col
# Color given as red-green-blue-alpha value.
export(Color, RGBA) var col
# Nodes
# Another node in the scene can be exported as a NodePath.
export(NodePath) var node_path
# Do take note that the node itself isn't being exported -
# there is one more step to call the true node:
onready var node = get_node(node_path)
# Resources
export(Resource) var resource
# In the Inspector, you can then drag and drop a resource file
# from the FileSystem dock into the variable slot.
# Opening the inspector dropdown may result in an
# extremely long list of possible classes to create, however.
# Therefore, if you specify an extension of Resource such as:
export(AnimationNode) var resource
# The drop-down menu will be limited to AnimationNode and all
# its inherited classes.
Nótese que incluso si el script no se ejecuta junto en el editor, las propiedades exportadas siguen siendo editables. Esto se puede utilizar en conjunto con un script en modo "tool".
Exportando "bit flags"¶
Los enteros usados como indicadores de bit (o bit flags) pueden guardar varios valores booleanos true
/false
en una sola propiedad. Usando el indicador de exportación int, FLAGS
, se pueden establecer desde el editor:
# Set any of the given flags from the editor.
export(int, FLAGS, "Fire", "Water", "Earth", "Wind") var spell_elements = 0
Debes proveer una cadena de descripción por cada bandera .En este ejemplo, Fire
tiene valor 1, Water
tiene valor 2, Earth
tiene valor 4 y Wind
corresponde al valor 8. Usualmente, las constantes deberían de definirse acorde a esto (p. ej. const ELEMENT_WIND = 8`` y así con el resto).
Los hints de exportación también se proveen para las capas de física y renderizado definidas en Ajustes de Proyecto:
export(int, LAYERS_2D_PHYSICS) var layers_2d_physics
export(int, LAYERS_2D_RENDER) var layers_2d_render
export(int, LAYERS_3D_PHYSICS) var layers_3d_physics
export(int, LAYERS_3D_RENDER) var layers_3d_render
Usar banderas requiere ciertos conocimientos de las operaciones bit a bit. En caso de duda, se pueden exportar variables booleanas en su lugar.
Exportando arrays¶
Los arrays exportados pueden tener inicializadores, pero deben ser expresiones constantes.
Si el array exportado especifica un tipo que hereda de Resource, se podrán asignar valores al array arrastrando y soltando múltiples archivos a la vez desde el panel de Sistema de Archivos.
# Default value must be a constant expression.
export var a = [1, 2, 3]
# Exported arrays can specify type (using the same hints as before).
export(Array, int) var ints = [1, 2, 3]
export(Array, int, "Red", "Green", "Blue") var enums = [2, 1, 0]
export(Array, Array, float) var two_dimensional = [[1.0, 2.0], [3.0, 4.0]]
# You can omit the default value, but then it would be null if not assigned.
export(Array) var b
export(Array, PackedScene) var scenes
# Arrays with specified types which inherit from resource can be set by
# drag-and-dropping multiple files from the FileSystem dock.
export(Array, Texture) var textures
export(Array, PackedScene) var scenes
# Typed arrays also work, only initialized empty:
export var vector3s = PoolVector3Array()
export var strings = PoolStringArray()
# Default value can include run-time values, but can't
# be exported.
var c = [a, 2, 3]
Configurando variables exportadas desde un script en modo tool¶
Cuando se cambia el valor de una variable exportada desde un script en Modo Tool, el valor en el inspector no se actualizará automaticamente. Para actualizarlo se debe llamar a :ref:`property_list_changed_notify() <class_Object_method_property_list_changed_notify>`después de asignar el valor a la variable exportada.
Exportación avanzada¶
No se proveen todos los tipos del lenguaje para export para evitar complejidad innecesaria. Lo siguiente describe las características de export más comunes que pueden implementarse con una API de bajo nivel.
Antes de seguir leyendo, deberías familiarizarte con el modo en que las propiedades son manejadas y cómo pueden ser personalizadas con _set(), _get(), y _get_property_list() Los métodos se describen en:ref:doc_accessing_data_or_logic_from_object.
Ver también
Para vincular propiedades usando los métodos mostrados anteriormente en C++, ver La vinculación de propiedades utilizando _set/_get/_get_property_list.
Advertencia
El script deberá funcionar en modo tool
para que los métodos mostrados funcionen en el editor.
Propiedades¶
Para comprender cómo usar mejor la siguiente sección, deberías entender como hacer propiedades con exports avanzado.
func _get_property_list():
var properties = []
# Same as "export(int) var my_property"
properties.append({
name = "my_property",
type = TYPE_INT
})
return properties
La funcion
_get_property_list()
es llamada por el inspector. Tu puedes sobre-escribirla para realizar exports más avanzados. Tu debes returnar un ``Array``con el contenido de las propiedades para que la función trabaje.name
es el nombre de la categoría que será agregada al inspectortype
es el tipo de la propiedad paraVariant.Type
.
Nota
El tipo float``es llamado un real (``TYPE_REAL
) en el enum Variant.Type
.
Acceder a variables locales o propiedades¶
Para agregar variables a propiedades (permitiendo el valor de la propiedad a ser usadas en scripts), necesitas crear una variable con el mismo nombre exacto a la propiedad o puedes necesitar reescribir los metodos _set() y _get(). Añadiendo una variable a la propiedad tambien te da la capacidad de darle un estado por defecto.
# This variable is determined by the function below.
# This variable acts just like a regular gdscript export.
var my_property = 5
func _get_property_list():
var properties = []
# Same as "export(int) var my_property"
properties.append({
name = "my_property",
type = TYPE_INT
})
return properties
Adicción de valores por defectos para propiedades¶
Para definir valores predeterminados a exports avanzados, necesitas re-escribir los métodos property_can_revert()``y ``property_get_revert()
.
El metodo
property_can_revert()
toma el nombre de una propiedad y tiene que retornartrue
si la propiedad puede ser revertida. Esto habilitará el botón Revert al lado de la propiedad en el inspector.El método
property_get_revert()
recibe el nombre de una propiedad y debe devolver el valor predeterminado para esa propiedad.
func _get_property_list():
var properties = []
properties.append({
name = "my_property",
type = TYPE_INT
})
return properties
func property_can_revert(property):
if property == "my_property":
return true
return false
func property_get_revert(property):
if property == "my_property":
return 5
Agragando categorías de script¶
Para una mejor distinción visual de las propiedades, se puede incrustar una categoría especial de script en el inspector para que actúe como separador. Script Variables
es un ejemplo de categoría incorporada.
func _get_property_list():
var properties = []
properties.append({
name = "Debug",
type = TYPE_NIL,
usage = PROPERTY_USAGE_CATEGORY | PROPERTY_USAGE_SCRIPT_VARIABLE
})
# Example of adding a property to the script category
properties.append({
name = "Logging_Enabled",
type = TYPE_BOOL
})
return properties
name
es el nombre de la categoría que será agregada al inspector;Cada propiedad que se agregue después de la definición de la categoría será parte de esa categoría.
PROPERTY_USAGE_CATEGORY
indica que la propiedad deberá ser tratada como una categoría de script específicamente, así que el tipoTYPE_NIL
puede ser ignorado y no se usará para la lógica de scripting, aún así debe ser definida.
Agrupando propiedades¶
Se puede agrupar una lista de propiedades con nombres similares.
func _get_property_list():
var properties = []
properties.append({
name = "Rotate",
type = TYPE_NIL,
hint_string = "rotate_",
usage = PROPERTY_USAGE_GROUP | PROPERTY_USAGE_SCRIPT_VARIABLE
})
# Example of adding to the group
properties.append({
name = "rotate_speed",
type = TYPE_REAL
})
# This property won't get added to the group
# due to not having the "rotate_" prefix.
properties.append({
name = "trail_color",
type = TYPE_COLOR
})
return properties
name
es el nombre del grupo que será mostrado como una lista plegable de propiedades;cada propiedad que sea agregada sucesivamente después de la propiedad de grupo, será colapsada y recortada según determine el prefijo definido mediante la clave
hint_string
. Por ejemplo,rotate_speed
será acortado comospeed
en este caso.PROPERTY_USAGE_GROUP``indica que la propiedad deberá ser tratada como un grupo de script específicamente, así que el ``TYPE_NIL
puede ser ignorado ya que no será usado para la lógica de scripting, igualmente debe ser definido.